Velocity/build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.github.jengelman.gradle.plugins:shadow:5.0.0'
    }
}

plugins {
    id 'java'
}

allprojects {
    group 'com.velocitypowered'
    version '1.1.0-SNAPSHOT'

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    ext {
        // dependency versions
        textVersion = '3.0.2'
        junitVersion = '5.3.0-M1'
        slf4jVersion = '1.7.25'
        log4jVersion = '2.11.2'
        nettyVersion = '4.1.42.Final'
        guavaVersion = '25.1-jre'
        checkerFrameworkVersion = '2.7.0'
        configurateVersion = '3.6'

        getCurrentShortRevision = {
            new ByteArrayOutputStream().withStream { os ->
                exec {
                    executable = "git"
                    args = ["rev-parse", "HEAD"]
                    standardOutput = os
                }
                return os.toString().trim().substring(0, 8)
            }
        }
    }

    repositories {
        mavenLocal()
        mavenCentral()
        
        // for kyoripowered dependencies
        maven {
            url 'https://oss.sonatype.org/content/groups/public/'
        }
        
        // Brigadier
        maven {
            url "https://libraries.minecraft.net"
        }

        // Configurate
        maven {
            name = 'sponge'
            url = 'https://repo.spongepowered.org/maven'
        }
    }

    test {
        reports {
            junitXml.enabled = true
        }
    }
}