Velocity/build.gradle

plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '2.0.4'
}

group 'com.velocitypowered'
version '1.0-SNAPSHOT'

sourceCompatibility = 1.8
targetCompatibility = 1.8

ext {
    // dependency versions
    junitVersion = '5.3.0-M1'
    log4jVersion = '2.11.0'
    nettyVersion = '4.1.28.Final'
}

repositories {
    mavenLocal()
    mavenCentral()
    maven {
        url 'https://oss.sonatype.org/content/groups/public/'
    }
}

dependencies {
    compile 'com.google.code.gson:gson:2.8.5'
    compile 'com.google.guava:guava:25.1-jre'
    compile "io.netty:netty-codec:${nettyVersion}"
    compile "io.netty:netty-codec-http:${nettyVersion}"
    compile "io.netty:netty-handler:${nettyVersion}"
    compile "io.netty:netty-transport-native-epoll:${nettyVersion}"
    compile "io.netty:netty-transport-native-epoll:${nettyVersion}:linux-x86_64"
    compile 'net.kyori:text:1.12-1.6.0-SNAPSHOT'
    compile "org.apache.logging.log4j:log4j-api:${log4jVersion}"
    compile "org.apache.logging.log4j:log4j-core:${log4jVersion}"
    compile 'com.moandjiezana.toml:toml4j:0.7.2'
    testCompile "org.junit.jupiter:junit-jupiter-api:${junitVersion}"
    testCompile "org.junit.jupiter:junit-jupiter-engine:${junitVersion}"
}

compileJava {
    options.compilerArgs += ['-proc:none']
}

compileTestJava {
    options.compilerArgs += ['-proc:none']
}

jar {
    manifest {
        attributes 'Main-Class': 'com.velocitypowered.proxy.Velocity'
        attributes 'Implementation-Version': project.version
    }
}

test {
    reports {
        junitXml.enabled = true
    }
}

task javadocJar(type: Jar) {
    classifier 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar
    archives shadowJar
    archives sourcesJar
}