/*
 * This file is a part of the SteamWar software.
 *
 * Copyright (C) 2021  SteamWar.de-Serverteam
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

plugins {
    id 'java'

    id 'com.github.johnrengelman.shadow'
}

group 'steamwar'
version ''

ext {
    buildName = 'FightSystem_Standalone'
    artifactName = 'FightSystem_Standalone'

    uberJarName = "${buildName}-all.jar"
    jarName = "${artifactName}.jar"
    libs = "${buildDir}/libs"
}

compileJava.options.encoding = 'UTF-8'

sourceCompatibility = 1.8
targetCompatibility = 1.8

sourceSets {
    main {
        java {
            srcDirs = []
        }
        resources {
            srcDirs = []
        }
    }
}

dependencies {
    file('../.').listFiles().each {
        if (!it.isDirectory()) {
            return
        }
        if (it.name.startsWith("FightSystem") && it.name != 'FightSystem_Standalone') {
            implementation project(":" + it.name)
        }
    }

    implementation swdep("SpigotCore")
}

task fixPluginYML(type: Copy) {
    from ("${projectDir}/../FightSystem_Core/src/") {
        include 'plugin.yml'
    }
    into "${projectDir}/build/resources/main/"
}
classes.finalizedBy(fixPluginYML)

task finalizeProject {
    description 'Finalize this project'
    group "Steamwar"

    doLast {
        if ("${buildDir}" == null) {
            return
        }
        delete fileTree("${libs}").matching {
            exclude("${uberJarName}")
        }
        file(libs + "/" + uberJarName).renameTo(file(libs + "/" + jarName))
    }
}
shadowJar.finalizedBy(finalizeProject)