/*
 * This file is a part of the SteamWar software.
 *
 * Copyright (C) 2020  SteamWar.de-Serverteam
 *
 * This program is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Affero General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
 * GNU Affero General Public License for more details.
 *
 * You should have received a copy of the GNU Affero General Public License
 * along with this program.  If not, see <https://www.gnu.org/licenses/>.
 */

plugins {
    id 'base'
    id 'java'
    id 'application'

    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'de.steamwar.gradle' version 'RELEASE'
}

group 'de.steamwar'
version ''

compileJava.options.encoding = 'UTF-8'

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
}

mainClassName = ''

sourceSets {
    main {
        java {
            srcDirs = ['src/']
        }
        resources {
            srcDirs = ['src/']
            exclude '**/*.java', '**/*.kt'
        }
    }
}

allprojects {
    repositories {
        mavenCentral()
        maven {
            url 'https://repo.papermc.io/repository/maven-public/'
            content {
                includeGroup 'com.velocitypowered'
            }
        }
        maven {
            url 'https://m2.dv8tion.net/releases'
            content {
                includeGroup 'net.dv8tion'
            }
        }
        maven {
            url 'https://repo.lunarclient.dev'
            content {
                includeGroup 'com.lunarclient'
            }
        }
    }
}

shadowJar {
    exclude 'META-INF/*'
    exclude 'org/sqlite/native/FreeBSD/**', 'org/sqlite/native/Mac/**', 'org/sqlite/native/Windows/**', 'org/sqlite/native/Linux-Android/**', 'org/sqlite/native/Linux-Musl/**'
    exclude 'org/sqlite/native/Linux/aarch64/**', 'org/sqlite/native/Linux/arm/**', 'org/sqlite/native/Linux/armv6/**', 'org/sqlite/native/Linux/armv7/**', 'org/sqlite/native/Linux/ppc64/**', 'org/sqlite/native/Linux/x86/**'
    exclude 'org/slf4j/**'
    //https://imperceptiblethoughts.com/shadow/configuration/minimizing/
    minimize {
        exclude project(':')
        exclude dependency('mysql:mysql-connector-java:.*')
    }
    duplicatesStrategy DuplicatesStrategy.INCLUDE
}

dependencies {
    compileOnly 'org.projectlombok:lombok:1.18.32'
    testCompileOnly 'org.projectlombok:lombok:1.18.32'
    annotationProcessor 'org.projectlombok:lombok:1.18.32'
    testAnnotationProcessor 'org.projectlombok:lombok:1.18.32'

    annotationProcessor 'com.velocitypowered:velocity-api:3.3.0-SNAPSHOT'
    compileOnly 'de.steamwar:velocity:RELEASE'

    compileOnly project(":Persistent")
    implementation project(":CommonCore")

    implementation 'org.xerial:sqlite-jdbc:3.46.0.0'
    implementation 'mysql:mysql-connector-java:8.0.33'

    implementation("net.dv8tion:JDA:4.4.0_352") {
        exclude module: 'opus-java'
    }

    implementation 'org.msgpack:msgpack-core:0.9.8' //AlpineClient

    implementation 'com.lunarclient:apollo-api:1.1.0'
    implementation 'com.lunarclient:apollo-common:1.1.0'
}