Mirror von
https://github.com/GeyserMC/Geyser.git
synchronisiert 2024-09-28 06:01:10 +02:00
9f32ba81b1
# Conflicts: # bootstrap/bungeecord/base/build.gradle.kts # bootstrap/spigot/base/build.gradle.kts # bootstrap/spigot/base/src/main/java/org/geysermc/geyser/platform/spigot/GeyserSpigotInjector.java # bootstrap/velocity/base/build.gradle.kts # core/build.gradle.kts # core/src/main/java/org/geysermc/geyser/GeyserImpl.java # core/src/main/java/org/geysermc/geyser/dump/DumpInfo.java # core/src/main/java/org/geysermc/geyser/entity/type/FireworkEntity.java # core/src/main/java/org/geysermc/geyser/network/netty/LocalSession.java # core/src/main/java/org/geysermc/geyser/session/GeyserSession.java # core/src/main/java/org/geysermc/geyser/translator/protocol/java/JavaCustomPayloadTranslator.java # core/src/main/java/org/geysermc/geyser/translator/protocol/java/JavaLoginTranslator.java # gradle.properties # gradle/libs.versions.toml # settings.gradle.kts
77 Zeilen
2.7 KiB
Plaintext
77 Zeilen
2.7 KiB
Plaintext
plugins {
|
|
id("geyser.publish-conventions")
|
|
}
|
|
|
|
dependencies {
|
|
api(projects.core)
|
|
api(libs.erosion.bukkit.common) {
|
|
isTransitive = false
|
|
}
|
|
|
|
implementation(variantOf(libs.adapters.spigot) {
|
|
classifier("all") // otherwise the unshaded jar is used without the shaded NMS implementations
|
|
})
|
|
implementation(variantOf(libs.adapters.paper) {
|
|
classifier("all") // otherwise the unshaded jar is used without the shaded NMS implementations
|
|
})
|
|
|
|
implementation(libs.commodore)
|
|
|
|
implementation(libs.adventure.text.serializer.bungeecord)
|
|
|
|
compileOnly(libs.folia.api)
|
|
compileOnly(libs.paper.mojangapi)
|
|
|
|
compileOnlyApi(libs.viaversion)
|
|
|
|
implementation(libs.floodgate.spigot)
|
|
compileOnly("com.mojang", "authlib", "1.5.21")
|
|
}
|
|
|
|
platformRelocate("it.unimi.dsi.fastutil")
|
|
platformRelocate("com.fasterxml.jackson")
|
|
// Relocate net.kyori but exclude the component logger
|
|
platformRelocate("net.kyori", "net.kyori.adventure.text.logger.slf4j.ComponentLogger")
|
|
platformRelocate("org.objectweb.asm")
|
|
platformRelocate("me.lucko.commodore")
|
|
platformRelocate("org.yaml") // Broken as of 1.20
|
|
|
|
// These dependencies are already present on the platform
|
|
provided(libs.viaversion)
|
|
provided("com.mojang", "authlib")
|
|
|
|
tasks.withType<com.github.jengelman.gradle.plugins.shadow.tasks.ShadowJar> {
|
|
|
|
// Prevents Paper 1.20.5+ from remapping Geyser
|
|
manifest {
|
|
attributes["paperweight-mappings-namespace"] = "mojang"
|
|
}
|
|
|
|
archiveBaseName.set("Geyser-Spigot")
|
|
|
|
dependencies {
|
|
exclude(dependency("com.google.*:.*"))
|
|
|
|
// We cannot shade Netty, or else native libraries will not load
|
|
// Needed because older Spigot builds do not provide the haproxy module
|
|
exclude(dependency("io.netty.incubator:.*"))
|
|
exclude(dependency("io.netty:netty-transport-classes-epoll:.*"))
|
|
exclude(dependency("io.netty:netty-transport-native-epoll:.*"))
|
|
exclude(dependency("io.netty:netty-transport-native-unix-common:.*"))
|
|
exclude(dependency("io.netty:netty-transport-classes-kqueue:.*"))
|
|
exclude(dependency("io.netty:netty-transport-native-kqueue:.*"))
|
|
exclude(dependency("io.netty:netty-handler:.*"))
|
|
exclude(dependency("io.netty:netty-common:.*"))
|
|
exclude(dependency("io.netty:netty-buffer:.*"))
|
|
exclude(dependency("io.netty:netty-resolver:.*"))
|
|
exclude(dependency("io.netty:netty-transport:.*"))
|
|
exclude(dependency("io.netty:netty-codec:.*"))
|
|
exclude(dependency("io.netty:netty-codec-dns:.*"))
|
|
exclude(dependency("io.netty:netty-resolver-dns:.*"))
|
|
exclude(dependency("io.netty:netty-resolver-dns-native-macos:.*"))
|
|
|
|
// Commodore includes Brigadier
|
|
exclude(dependency("com.mojang:.*"))
|
|
}
|
|
}
|