plugins {
    id 'fabric-loom'
}

tasks.withType(JavaCompile) {
    options.release = 17
}

version = project.version
group = 'de.chaoscaot'

sourceSets {
    main {
        java {
            srcDirs = ['src/']
        }
        resources {
            srcDirs = ['src/']
            exclude '**/*.java'
        }
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modCompileOnly "net.fabricmc:fabric-loader:${project.loader_version}"
    modCompileOnlyApi ("me.shedaniel.cloth:cloth-config-fabric:8.2.88") {
        exclude(group: "net.fabricmc.fabric-api")
    }
    modCompileOnlyApi "com.terraformersmc:modmenu:4.0.6"
    compileOnly project(":common")
}

processResources {
    inputs.property "version", project.version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version, "minecraftVersion": project.minecraft_version, "loaderVersion": project.loader_version
    }
}

loom {
    accessWidenerPath = file("src/altauth.accesswidener")
}